***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 31, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZT52-C4V3 A K 
.param
+vc0 = 3.346e-10	vc1 = 2.516e-9		vc2 = 1.500		vc3 = 1.606e-9		vc4 = 9.952
+tc1 = 2.681e-3		tc2 = 4.821e-3		tc3 = 3.401e-3		tc4 = 4.021e-3
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.063e-15	   n = 1.050		  rs = 4.283e-1
+ibv = 1e-3		 nbv = 4.0		  bv = 4.3
+ikf = 1.000e-1
***** capacitance parameter *****
+cjo = 1.525e-10	   m = 3.393e-1		  vj = 7.000e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.134		 xti = 3
+trs1 = 9.525e-4	trs2 = 7.085e-6		tikf = 6e-3
+tbv1 = -3.238e-4	tbv2 = 1.532e-7	
.ends BZT52-C4V3
*$
